Parted-2 Post Processing

Messing With Stereo And Reflections

Recently I posted over on Nerds-Central a piece called Parted. This render was done in two stages. The first patch produced the basic sounds however, the post processing step added stereo depth.

"temp/parted-1.wav"      !wavFile
?wavFile ReadFile          !channels
?channels GetStart         !left
>channels GetRest GetStart !right
(
    (?left !lefto,1500,1)DirectLowPassBessel,
    >left dbs-3
)Mix Normalise !left
(
    (?right !righto,1500,1)DirectHighPassBessel,
    >right dbs-3
 )Mix Normalise !right

(
    (>right,0),
    (?lefto dbs-18,80),
    (?lefto dbs-18,260),
    (?lefto dbs-18,340)
)MixAt !right
 
(
    (>left,0),
    (?righto dbs-18,120),
    (?righto dbs-18,250),
    (?righto dbs-18,330)
)MixAt !left
 
(
    (
        (1000 Silence,>left Normalise)Concatenate,
        (1000 Silence,>right Normalise)Concatenate
    ),
    "temp/parted-2.wav"
)WriteFile32

 The first bit takes a stereo (2 channel) wav file and reads it into two separate audio signals:

"temp/parted-1.wav"      !wavFile
?wavFile ReadFile          !channels
?channels GetStart         !left
>channels GetRest GetStart !right

The input here was pure stereo; the render was effectively done twice, one for each channel. As quite a lot of the detailing in the piece comes from random numbers, the two channels were subtly different, especially in the reverb. However, the effect was a little cold and artificial. The next steps helped sort that out.

(
    (?left !lefto,1500,1)DirectLowPassBessel,
    >left dbs-3
)Mix Normalise !left
(
    (?right !righto,1500,1)DirectHighPassBessel,
    >right dbs-3
 )Mix Normalise !right 

These gave left and right very slightly different tonal differences. More highs on the right and more lows on the left. I used Bessel filters to avoid 'phasing' effects when mixing back with the original otherwise the result might have sounded like a 1970 pop song!

(
    (>right,0),
    (?lefto dbs-18,80),
    (?lefto dbs-18,260),
    (?lefto dbs-18,340)
)MixAt !right
   
(
    (>left,0),
    (?righto dbs-18,120),
    (?righto dbs-18,250),
    (?righto dbs-18,330)
)MixAt !left

These added a few early reflections to the audio which already had reverberation in it. The effect of this it to add a really etherial sound and completely confuse the brain. It is not possible to properly imagine a space which would have this audio structure to it, so the sound just becomes 'other worldly'.

(
    (
        (1000 Silence,>left Normalise)Concatenate,
        (1000 Silence,>right Normalise)Concatenate
    ),
    "temp/parted-2.wav"
)WriteFile32

It is always important to put some silence before a piece starts to allow the audio player (itunes, youtube or what ever) to get started. Here I added 1 second. Actually, I think this is a little too little and should have added 2 seconds.